Come si analizza JSON in Racket?

Question

Non riesco a capire {documentation}, non ci sono davvero esempi di analisi di alcuni semplici dati JSON, quindi mi chiedevo se qualcuno qui potesse darmi qualche esempio per iniziare.

Answer 1

Ecco un esempio molto semplice:

(require json) 
(define x (string->jsexpr "{\"foo\": \"bar\", \"bar\": \"baz\"}")) 
(for (((key val) (in-hash x))) 
    (printf "~a = ~a~%" key val)) 

Ecco come è possibile utilizzarlo con un'API JSON-based:

(require net/http-client json) 
(define-values (status header response) 
    (http-sendrecv "httpbin.org" "/ip" #:ssl? 'tls)) 
(define data (read-json response)) 
(printf "My IP address is ~a~%" (hash-ref data 'origin)) 

Su richiesta del PO, ecco come si può creare un valore JSON da un tipo di struttura:

(require json) 
(struct person (first-name last-name age country)) 
(define (person->jsexpr p) 
    (hasheq 'first-name (person-first-name p) 
      'last-name (person-last-name p) 
      'age (person-age p) 
      'country (person-country p))) 
(define cky (person "Chris" "Jester-Young" 33 "New Zealand")) 
(jsexpr->string (person->jsexpr cky))