CMake - impostazione python virtualenv

Question

Vorrei il mio progetto che è stato costruito con porzioni in cmake - per fare in modo che cmake configuri virtualenv per il mio codice python.

Questo di solito è fatto o dovrei solo presumere che il mio ambiente python sarà globale?

Answer 1

Il succo collegato funziona

cmake_minimum_required(VERSION 3.6) 

project(CmakeVirtualenv) 

enable_testing() 

# Find Python and Virtualenv. We don't actually use the output of the 
# find_package, but it'll give nicer errors. 
find_package(PythonInterp 2.7 REQUIRED) 
find_program(VIRTUALENV virtualenv) 
if(NOT VIRTUALENV) 
    message(FATAL_ERROR "Could not find `virtualenv` in PATH") 
endif() 
set(VIRTUALENV ${VIRTUALENV} -p python2.7) 

# Generate the virtualenv and ensure it's up to date. 
add_custom_command(
    OUTPUT venv 
    COMMAND ${VIRTUALENV} venv 
) 
add_custom_command(
    OUTPUT venv.stamp 
    DEPENDS venv requirements.txt 
    COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/requirements.txt requirements.txt 
    COMMAND ./venv/bin/pip install -r requirements.txt --upgrade 
) 

# Build command line to run py.test. 
set(PYTEST 
    ${CMAKE_CURRENT_BINARY_DIR}/venv/bin/python2 
    ${CMAKE_CURRENT_BINARY_DIR}/venv/bin/py.test 
) 


add_custom_target(Tests ALL 
    DEPENDS venv.stamp 
    SOURCES requirements.txt 
) 

add_test(NAME run_tests 
    COMMAND ${PYTEST} ${CMAKE_CURRENT_SOURCE_DIR}/test_sample.py 
) 

Si noti che potrebbe essere necessario utilizzare ${CMAKE_CURRENT_BINARY_PATH/venv} o simili se si utilizza WORKING_DIRECTORY per ignorare la directory di lavoro corrente.