Come posso sfuggire a una stringa letterale che voglio interpolare in un'espressione regolare?

Question

Esiste un modo integrato per evitare una stringa che verrà utilizzata all'interno di/come espressione regolare? Per esempio.

www.abc.com 

La sfuggito versione sarebbe:

www\.abc\.com 

Stavo per usare:

$string =~ s/[.*+?|()\[\]{}\\]/\\$&/g; # Escapes special regex chars 

Ma volevo solo fare in modo che non ci sia un pulitore incorporato operazione che Mi manca?

Answer 1

Utilizzare quotemeta o \Q...\E.

Si consideri il seguente programma di test che corrisponde contro $str così com'è, con quotemeta, e con \Q...\E:

#! /usr/bin/perl 

use warnings; 
use strict; 

my $str = "www.abc.com"; 

my @test = (
    "www.abc.com", 
    "www/abc!com", 
); 

sub ismatch($) { $_[0] ? "MATCH" : "NO MATCH" } 

my @match = (
    [ as_is => sub { ismatch /$str/ } ], 
    [ qmeta => sub { my $qm = quotemeta $str; ismatch /$qm/ } ], 
    [ qe => sub { ismatch /\Q$str\E/ } ], 
); 

for (@test) { 
    print "\$_ = '$_':\n"; 

    foreach my $method (@match) { 
    my($name,$match) = @$method; 

    print " - $name: ", $match->(), "\n"; 
    } 
} 

Avviso nell'output che utilizzando la stringa così com'è potrebbe produrre risultati spuri:

 
$ ./try 
$_ = 'www.abc.com': 
    - as_is: MATCH 
    - qmeta: MATCH 
    - qe: MATCH 
$_ = 'www/abc!com': 
    - as_is: MATCH 
    - qmeta: NO MATCH 
    - qe: NO MATCH 

Per i programmi che accettano input non attendibili, prestare estrema attenzione all'utilizzo di bit potenzialmente sgradevoli come espressioni regolari: così facendo si potrebbero creare errori di runtime imprevisti, negazione di sé vulnerabilità dei servizi e buchi di sicurezza.

Answer 2

Il modo migliore per farlo è utilizzare \Q per iniziare una stringa tra virgolette e \E per terminarlo.

my $foo = 'www.abc.com'; 
$bar =~ /blah\Q$foo\Eblah/; 

È inoltre possibile utilizzare quotemeta sulla variabile. Per esempio.

my $quoted_foo = quotemeta($foo); 

Il \Q trucco è documentato in perlre sotto "Sequenze di escape."