Il modo migliore per lavorare con le transazioni in MS SQL Server Management Studio

Question

Diciamo che ho un'istruzione SQL che è sintatticamente e semanticamente corretta in modo che venga eseguita.

In Management Studio (o qualsiasi altro strumento di query) come posso testare istruzioni SQL, e se mi accorgo che hanno rotto qualcosa, rollback (in una query separata?)

Answer 1

La cosa easisest fare è di avvolgere il tuo codice in una transazione, quindi esegui ogni batch di codice T-SQL riga per riga.

Per esempio,

Begin Transaction 

     -Do some T-SQL queries here. 

Rollback transaction -- OR commit transaction 

Se si desidera incorporare la gestione è possibile farlo utilizzando una TRY ... CATCH BLOCK errore. Se si verifica un errore, è possibile eseguire il rollback della transizione all'interno del blocco catch.

Ad esempio:

USE AdventureWorks; 
GO 
BEGIN TRANSACTION; 

BEGIN TRY 
    -- Generate a constraint violation error. 
    DELETE FROM Production.Product 
    WHERE ProductID = 980; 
END TRY 
BEGIN CATCH 
    SELECT 
     ERROR_NUMBER() AS ErrorNumber 
     ,ERROR_SEVERITY() AS ErrorSeverity 
     ,ERROR_STATE() AS ErrorState 
     ,ERROR_PROCEDURE() AS ErrorProcedure 
     ,ERROR_LINE() AS ErrorLine 
     ,ERROR_MESSAGE() AS ErrorMessage; 

    IF @@TRANCOUNT > 0 
     ROLLBACK TRANSACTION; 
END CATCH; 

IF @@TRANCOUNT > 0 
    COMMIT TRANSACTION; 
GO 

vedere il seguente link per maggiori informazioni.

http://msdn.microsoft.com/en-us/library/ms175976.aspx

Spero che questo aiuti, ma per favore fatemi sapere se avete bisogno di ulteriori dettagli.

Answer 2

Voglio aggiungere un punto che è possibile anche (e dovrebbe se ciò che si sta scrivendo è complesso) aggiungere una variabile di prova al rollback se si è in modalità test. Quindi puoi eseguire l'intera operazione in una sola volta. Spesso aggiungo anche il codice per vedere i risultati precedenti e successivi di varie operazioni, specialmente se si tratta di uno script complesso.

Esempio di seguito:

USE AdventureWorks; 
GO 
DECLARE @TEST INT = 1--1 is test mode, use zero when you are ready to execute 
BEGIN TRANSACTION; 

BEGIN TRY 
    IF @TEST= 1 
     BEGIN 
      SELECT *FROM Production.Product 
       WHERE ProductID = 980; 
     END  
    -- Generate a constraint violation error. 
    DELETE FROM Production.Product 
    WHERE ProductID = 980; 

    IF @TEST= 1 
     BEGIN 
      SELECT *FROM Production.Product 
       WHERE ProductID = 980; 
      IF @@TRANCOUNT > 0 
       ROLLBACK TRANSACTION; 
     END  
END TRY 

BEGIN CATCH 
    SELECT 
     ERROR_NUMBER() AS ErrorNumber 
     ,ERROR_SEVERITY() AS ErrorSeverity 
     ,ERROR_STATE() AS ErrorState 
     ,ERROR_PROCEDURE() AS ErrorProcedure 
     ,ERROR_LINE() AS ErrorLine 
     ,ERROR_MESSAGE() AS ErrorMessage; 

    IF @@TRANCOUNT > 0 
     ROLLBACK TRANSACTION; 
END CATCH; 

IF @@TRANCOUNT > 0 AND @TEST = 0 
    COMMIT TRANSACTION; 
GO