Verificare se qualsiasi tipo di file esiste in una directory utilizzando script batch

Question

Ciao Sto cercando di scrivere un file batch per controllare per vedere se ci sono dei file di qualsiasi tipo all'interno di una determinata cartella.

Finora ho provato la seguente

if EXIST FOLDERNAME\\*.* (echo Files Exist) ELSE (echo "Empty") 

posso farlo funzionare se conosco l'estensione del file, ad esempio un file txt con il follwing

if EXIST FOLDERNAME\\*.txt (echo Files Exist) ELSE (echo "Empty") 

Grazie per la vostra aiutare

Answer 1

È possibile utilizzare questo

@echo off 
for /F %%i in ('dir /b "c:\test directory\*.*"') do (
    echo Folder is NON empty 
    goto :EOF 
) 
echo Folder is empty or does not exist 

Tratto da here.

Questo dovrebbe fare quello che ti serve.

Answer 2

Per verificare se una cartella contiene almeno un file

>nul 2>nul dir /a-d "folderName\*" && (echo Files exist) || (echo No file found) 

Per verificare se una cartella o uno dei suoi discendenti contengono almeno un file

>nul 2>nul dir /a-d /s "folderName\*" && (echo Files exist) || (echo No file found) 

Per verificare se una cartella contiene almeno un file o una cartella.
Nota aggiunta di /a opzione per abilitare ritrovamento di file/cartelle nascoste e di sistema.

dir /b /a "folderName\*" | >nul findstr "^" && (echo Files and/or Folders exist) || (echo No File or Folder found) 

Per verificare se una cartella contiene almeno una cartella

dir /b /ad "folderName\*" | >nul findstr "^" && (echo Folders exist) || (echo No folder found) 

Answer 3

Per i file in una directory, è possibile utilizzare le cose come:

if exist *.csv echo "csv file found" 

o

if not exist *.csv goto nofile