Delphi - ereditarietà dell'interfaccia con i generici

Question

Attualmente sono bloccato con un errore di compilazione, nessuno nella nostra azienda può aiutare e purtroppo non trovo i modelli di ricerca corretti per SO o google.

Come codice sto usando 2 interfacce, ereditate e 2 classi, ereditate. Il seguente codice riproduce l'errore:

program Project22; 

{$APPTYPE CONSOLE} 
type 
    IStorageObject = interface(IInterface) 
    end; 
    TObjectStorage<T: IStorageObject> = class(TObject) 
    end; 
    IKeyStorageObject<TKey> = interface(IStorageObject) 
    end; 
    TKeyObjectStorage<TKey, T: IKeyStorageObject<TKey>> = class(TObjectStorage<T>) 
    end; 
    TImplementingClass<TKey> = class(TInterfacedObject, IKeyStorageObject<TKey>) 
    end; 
begin 
    TKeyObjectStorage<Integer, TImplementingClass<Integer>>.Create; 
end. 

L'errore del compilatore per 'TKeyObjectStorage' è:

[DCC Error] Project22.dpr(11): E2514 Type parameter 'T' must support interface 'IStorageObject'

Quello che penso è che il compilatore non riconosce tale parametro T del TKeyObjectStorage della classe' 'correttamente. Dovrebbe essere corretto, poiché il tipo desiderato "IKeyStorageObject" ha il tipo principale IStorageObject.

Perché non funziona? Che cosa sto facendo di sbagliato? Non è possibile a Delphi?

Answer 1

Aggiornamento

La domanda originale aveva un problema che ho individuato (vedi sotto). Tuttavia, la correzione che descrivo è valida per XE3 e versioni successive, ma il programma riportato di seguito non viene compilato in XE2. Quindi concludo che questo è un bug del compilatore generico XE2.

In ogni caso, ecco una soluzione per Delphi XE2:

{$APPTYPE CONSOLE} 
type 
    IStorageObject = interface(IInterface) 
    end; 
    TObjectStorage<T: IStorageObject> = class(TObject) 
    end; 
    IKeyStorageObject<TKey> = interface(IStorageObject) 
    end; 
    TKeyObjectStorage<TKey; T: IKeyStorageObject<TKey>, IStorageObject> = class(TObjectStorage<T>) 
    end; 
    TImplementingClass<TKey> = class(TInterfacedObject, IStorageObject, IKeyStorageObject<TKey>) 
    end; 
begin 
    TKeyObjectStorage<Integer, TImplementingClass<Integer>>.Create; 
end. 

---

risposta originale

Sarebbe stato meglio se si fosse previsto un programma completo che espone l'errore del compilatore . È necessario tentare di creare un'istanza di un oggetto per vedere quell'errore.

Ma, penso di aver riprodotto il tuo problema. Quindi credo che il problema è che questo codice:

TKeyObjectStorage<TKey, T: IKeyStorageObject<TKey>> = ... 

vale il vincolo generico sia TKey e T. Ora, chiaramente desideri solo il vincolo da applicare al T quindi è necessario scrivere:

TKeyObjectStorage<TKey; T: IKeyStorageObject<TKey>> = ... 

Ecco un breve programma che compila in seguito alla modifica Delphi XE3:

{$APPTYPE CONSOLE} 
type 
    IStorageObject = interface(IInterface) 
    end; 
    TObjectStorage<T: IStorageObject> = class(TObject) 
    end; 
    IKeyStorageObject<TKey> = interface(IStorageObject) 
    end; 
    TKeyObjectStorage<TKey; T: IKeyStorageObject<TKey>> = class(TObjectStorage<T>) 
    end; 
    TImplementingClass<TKey> = class(TInterfacedObject, IKeyStorageObject<TKey>) 
    end; 
begin 
    TKeyObjectStorage<Integer, TImplementingClass<Integer>>.Create; 
end. 

Questo è piuttosto una sfumatura, il cambio di una virgola in un punto e virgola. Programmare con una punteggiatura significativa non è mai molto divertente. Detto questo, hai familiarità con la differenza tra virgole e punti e virgola in liste parametriche formali e quindi non dovrebbe essere troppo sorprendente vedere la stessa distinzione tracciata qui.

Il documentation fa coprire questo si badi bene:

Multiple Type Parameters

When you specify constraints, you separate multiple type parameters by semicolons, as you do with a parameter list declaration:

type 
    TFoo<T: ISerializable; V: IComparable> 

Like parameter declarations, multiple type parameters can be grouped together in a comma list to bind to the same constraints:

type 
    TFoo<S, U: ISerializable> ... 

In the example above, S and U are both bound to the ISerializable constraint.