Flex: implementazione della classica funzione curry in ActionScript?

Question

Qual è il modo migliore per implementare una classica funzione curry in actionscript con una bella sintassi?

ho provato:

Function.prototype.curry = function() 
{ 
return "helloWorld"; 
} 

trace((function():void {}).curry()); 

... approccio, ma che non ha funzionato.

credo di essere bloccato con un approccio brutta come ad esempio:

FunctionUtils.curry(fp, ... args) 

???

Answer 1

Devo ammettere che non ho mai capito la differenza tra "curry" e "partial". Io uso la seguente funzione di fare più o meno quello che si vuole fare:

package { 
    public function partial(func : Function, ...boundArgs) : Function { 
    return function(...dynamicArgs) : * { 
     return func.apply(null, boundArgs.concat(dynamicArgs)) 
    } 
    } 
} 

Esempi di utilizzo:

var multiply : Function = function(a : Number, b : Number) : Number { return a * b; } 
var multiplyByFour : Function = partial(multiply, 4); 

trace(multiplyByFour(3)); // => 12 

Answer 2

finito con (fortemente ispirato dalla implementazione del dojo):

public static function curry(func:Function, ... args:Array):* 
{ 
    var arity:int = func.length; 
    var currying:Function = function(func:Function, arity:int, args:Array):* 
    { 
     return function(... moreArgs:Array):* { 
      if(moreArgs.length + args.length < arity) 
      { 
       return currying(func, arity, args.concat(moreArgs)); 
      } 
      return func.apply(this, args.concat(moreArgs)); 
     } 
    } 
    return currying(func, arity, args); 
} 

richiesta nella sezione commenti per mostrare un esempio di come usare questo:

function foo(i:int, j:int):void 
{ 
    trace(i+j); 
} 

function bar(fp:Function):void 
{ 
    fp(2); 
} 

bar(FunctionUtils.curry(foo, 1)); //trace==3 

esempio stupido, lo so, ma curry: ing è estremamente utile. Dai un'occhiata a http://www.svendtofte.com/code/curried_javascript/ per la teoria.