Gnuplot: Impostare la gamma di un terzo punto (colorato)

Question

Quando la stampa a colori-mappe con gnuplot, io di solito uso le seguenti righe:

... 
    set palette rgbformulae 33,13,10 
    plot "file.dat" using 1:2:3 with points pointtype '7' palette 

Di solito la gamma del terzo punto (che compare nella leggenda) viene automaticamente impostato da gnuplot. Ma come posso cambiarlo? dire che voglio la gamma del 3 ° punto di essere da 0 a 1500.

Qualche suggerimento?

Answer 1

Questa è davvero una buona domanda - assumendo si intenda che si desidera determinare l'intervallo della barra di colore (non la legenda [chiave i.e] - la legenda in genere non ha quell'informazione).

Il mio primo pensiero è stato set cbrange. Questo potrebbe fare quello che vuoi - "Cosa vuoi che accada al di punti di campo"

set cbrange [0:1500] 
set palette rgbformulae 33,13,10 
plot "file.dat" u 1:2:3 w p pt 7 palette 

Tuttavia, la questione è quindi Questa soluzione si sposterà dai punti dell'intervallo fino alla parte inferiore/superiore della scala (ad esempio viola per numeri negativi, rosso per numeri maggiori di 1500). Il mio prossimo pensiero è stato che dovresti essere in grado di tagliare quei punti con set zrange [0:1500] - Ma non funziona. Hai almeno 2 opzioni a questo punto.

Opzione 1: uso splot:

set view map 
set cbrange [0:1500] 
set zrange [0:1500] 
set palette rgbformulae 33,13,10 
splot "file.dat" u 1:2:3 w p pt 7 palette 

vostri confini saranno leggermente diverso rispetto a prima, ma questo è nessun vero grosso problema.

Opzione 2: filtro con l'operatore ternario (che già si conosce dalla tua domanda precedente):

set cbrange [0:1500] 
set palette rgbformulae 33,13,10 
inrange(c)=((c>=0) && (c<=1500))? c : (1/0) 
plot "file.dat" u 1:2:(inrange($3)) w p pt 7 palette 

Inoltre, per il tracciato mappe di colore, si consiglia di guardare nello stile pm3d plotting (image potrebbe funzionare anche). Potresti aver bisogno di ristrutturare leggermente il tuo file di dati, ma tracciare mappe dei colori è quello di plottare lo stile del pane e burro.