Come esportare numeri interi usando il metodo Put_Line?

Question

non posso trovare questo programma per la compilazione perché non sembra stampare variabili intere insieme con le stringhe nel metodo Put_Line. Ho guardato il codice sorgente online e funziona quando lo fanno, quindi dove sto andando male. Grazie per l'aiuto.

with Ada.Text_IO;      use Ada.Text_IO; 
with Ada.Integer_Text_IO;   use Ada.Integer_Text_IO; 

procedure MultiplicationTable is 

    procedure Print_Multiplication_Table(Number :in Integer; Multiple :in Integer) is 
     Result : Integer; 
    begin 
     for Count in 1 ..Multiple 
     loop 
      Result := Number * Count; 
      Put_Line(Number & " x " & Count & " = " & Result); 
     end loop; 
    end Print_Multiplication_Table; 
    Number : Integer; 
    Multiple : Integer; 

begin 
    Put("Display the multiplication of number: "); 
    Get(Number); 
    Put("Display Multiplication until number: "); 
    Get(Multiple); 
    Print_Multiplication_Table(Number,Multiple); 
end MultiplicationTable;` 

Answer 1

Il problema è che si sta utilizzando & con le stringhe e numeri interi. Provare una delle seguenti opzioni:

Sostituire Number all'interno del parametro della put con Integer'Image(Number)

o rompere il Put_Line nelle componenti che si desidera; es:

-- Correction to Put_Line(Number & " x " & Count & " = " & Result); 
Put(Number); 
Put(" x "); 
Put(Count); 
Put(" = "); 
Put(Result); 
New_Line(1); 

Answer 2

Prova questa:

Put_Line(Integer'Image(Number) & " x " & Integer'Image(Count) & " = " & Integer'Image(Result)); 

Answer 3

Sei già with e use clausole per Ada.Integer_Text_IO, ma non si sta usando esso.

Modifica questo:

Put_Line(Number & " x " & Count & " = " & Result); 

a questo:

Put(Number); Put(" x "); Put(Count); Put(" = "); Put(Result); New_Line; 

(normalmente non avrebbe messo più istruzioni su una linea, ma in questo caso ha senso.)

Si noti che Integer'Image antepone gli interi non negativi con uno spazio, cosa che ho sempre trovato molto fastidioso; Ada.Integer_Text_IO.Put non lo fa (a meno che tu non lo chieda).

È potrebbe define sovraccarico "&" funzioni, qualcosa di simile:

function "&"(Left: String; Right: Integer) return String is 
begin 
    return Left & Integer'Image(Right); 
end "&"; 

function "&"(Left: Integer; Right: String) return String is 
begin 
    return Integer'Image(Left) & Right; 
end "&"; 

che renderebbe il vostro Put_Line chiamata originale valido, ma il multiplo Put chiamate sono in stile probabilmente meglio.

Answer 4

Costruire sulla risposta (e un commento in un'altra domanda) da Keith Thompson, qui è un programma completo Ada in grado di stringhe di output e interi con &, utilizzando Put_Line, ma senza gli spazi che Integer'Image altrimenti anteporre:

with Ada.Text_IO; use Ada.Text_IO; 
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO; 

procedure Main is 

function lstrip(S: String) return String is 
begin 
    if S(S'First) = ' ' then 
     return S(S'First+1 .. S'Last); 
    else 
     return S; 
    end if; 
end; 

function "&"(Left: String; Right: Integer) return String is 
begin 
    return Left & lstrip(Integer'Image(Right)); 
end "&"; 

function "&"(Left: Integer; Right: String) return String is 
begin 
    return lstrip(Integer'Image(Left)) & Right; 
end "&"; 

begin 
    Put_Line("x=" & 42); 
end Main;