Esiste un modo idiomatico per testare l'uguaglianza dell'array in Coffeescript?

Question

L'espressione

[1, 2, 3] == [1, 2, 3] 

viene valutato come false in CoffeeScript ma c'è un modo idiomatica conciso per testare l'uguaglianza array?

Answer 1

Se avete a che fare con le matrici di numeri, e si sa che non ci sono nulli o valori non definiti nel vostro array, è possibile confrontare come stringhe:

a = [1, 2, 3] 
b = [1, 2, 3] 

console.log "#{a}" is "#{b}" # true 
console.log '' + a is '' + b # true 

noti, tuttavia, che questo si romperà, non appena si inizia a matrici di confronto di altre cose che non sono numeri:

a = [1, 2, 3] 
b = ['1,2', 3] 

console.log "#{a}" is "#{b}" # true 

Se si desidera una soluzione più robusta, è possibile utilizzare Array#every:

arrayEqual = (a, b) -> 
    a.length is b.length and a.every (elem, i) -> elem is b[i] 

console.log arrayEqual [1, 2, 3], [1, 2, 3] # true 
console.log arrayEqual [1, 2, 3], [1, 2, '3'] # false 
console.log arrayEqual [1, 2, 3], ['1,2', 3] # false 

Si noti che per prima cosa si confrontano le lunghezze degli array in modo che arrayEqual [1], [1, 2, 3] non restituisca true.

Answer 2

Se non ti interessa introdurre una dipendenza Underscore.js, potresti utilizzare alcune delle sue utilità. Non è massicciamente elegante, ma non riesco a pensare a un modo più semplice per farlo con CoffeeScript pianura:

a = [ 1, 2, 3 ] 
b = [ 1, 2, 3 ] 
equal = a.length == b.length and _.all(_.zip(a, b), ([x,y]) -> x is y) 

Answer 3

non vorrei prendere in considerazione questa idiomatica, ma questo sarebbe un modo di farlo senza l'aggiunta di una libreria in più :

a = [1, 2, 3, 4] 
b = [22, 3, 4] 

areEqual = true 
maxIndex = Math.max(a.length, b.length)-1 
for i in [0..maxIndex] 
    testEqual = a[i] is b[i] 
    areEqual = areEqual and testEqual 

console.log areEqual 

Un approccio più pulito sarebbe utilizzando la funzione di JavaScript reduce(). Questo è un po 'più breve, ma non sono sicuro che tutti i browser supportino la riduzione.

a = [1, 3, 4, 5] 
b = [1, 3, 4, 5] 

maxIndex = Math.max(a.length, b.length)-1 
areEqual = true 
[0..maxIndex].reduce (p, c, i, ar) -> areEqual = areEqual and (a[i] is b[i]) 

console.log "areEqual=#{areEqual}" 

Answer 4

Sono un grande fan di Sugar.js. Se vi capita di essere utilizzando tale:

a = [1, 2, 3] 
b = [1, 2, 3] 
Object.equal(a, b) 

Answer 5

Il seguente funziona alla grande e non richiede dipendenze:

arrayEqual = (ar1, ar2) -> 
    JSON.stringify(ar1) is JSON.stringify(ar2) 

Answer 6

Questa funzione restituisce true se gli array hanno stessa lunghezza e tutti i valori con lo stesso indice di avere lo stesso valore. Genera un errore se uno degli argomenti non è un array.

isArray = Array.isArray || (subject) -> 
    toString.call(subject) is '[object Array]' 

compareArrays = (a, b) -> 
    unless isArray(a) and isArray b 
     throw new Error '`arraysAreEqual` called with non-array' 

    return false if a.length isnt b.length 

    for valueInA, index in a 
     return false if b[index] isnt valueInA 

    true