Lettura valori distinti da XML utilizzando XPath

Question

Ho un XML nel seguente formato:

<Accounts> 
    <Account Number="1" DebitAmount="1000" Amount="2827561.95" /> 
    <Account Number="225" DebitAmount="2000" Amount="12312.00" /> 
    <Account Number="236" DebitAmount="London" Amount="457656.00" /> 
    <Account Number="225" DebitAmount="London" Amount="23462.40" /> 
    <Account Number="236" DebitAmount="Bangalore" Amount="2345345.00" /> 
</Accounts> 

Come faccio a prelevare i numeri di conto unici utilizzando XPath? vale a dire, voglio ottenere i valori 1, 225 e 236.

Questo è quello che ho fatto: (sto usando Delphi 2007 ...)

Const XmlStr = 
' <Accounts> 
    <Account Number="1" DebitAmount="1000" Amount="2827561.95" /> 
    <Account Number="225" DebitAmount="2000" Amount="12312.00" /> 
    <Account Number="236" DebitAmount="London" Amount="457656.00" /> 
    <Account Number="225" DebitAmount="London" Amount="23462.40" /> 
    <Account Number="236" DebitAmount="Bangalore" Amount="2345345.00" /> 
</Accounts>'; 

function GetAccountNumbers:TList; 
Var 
    XMLDOMDocument : IXMLDOMDocument; 
    accounts : IXMLDOMNodeList; 
    accountdetail :IXMLDOMNode; 
    i:Integer 
    list :TList 
begin 
    Result:=TList.Create; 
    XMLDOMDocument:=CoDOMDocument.Create; 
    XMLDOMDocument.loadXML(XmlStr); 
    accounts:= XMLDOMDocument.SelectNodes(''./Accounts 
    /Account[not(@Number=preceding-sibling/ Account /@Number)]'); 
    for i := 0 to accountdetails.length - 1 do begin 
    accountdetail := accountdetails.item[i]; 
    //omitting the "<>nil" checks... 
    list.Add(accountdetail.attributes.getNamedItem('Number').Nodevalue; 
    end; 
end; 

Ma questo non ha prodotto alcun nodi (accountdetails. lunghezza = 0). Per favore fatemi sapere cosa mi manca qui.

Grazie,

Pradeep

Answer 1

Sembra che la versione di MSXML di Delphi 2007 non supporti l'asse XPath. Quindi, se si decide di utilizzare il seguente codice, l'importazione sia Microsoft XML, v3.0 o la libreria Microsoft XML, v6.0 tipo e poi provare questo:

unit Unit1; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, StdCtrls, MSXML2_TLB; 

type 
    TForm1 = class(TForm) 
    Button1: TButton; 
    procedure Button1Click(Sender: TObject); 
    private 
    { Private declarations } 
    public 
    { Public declarations } 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

const 
    XMLString = 
    '<Accounts>' + 
    '<Account Number="1" DebitAmount="1000" Amount="2827561.95"/>' + 
    '<Account Number="225" DebitAmount="2000" Amount="12312.00"/>' + 
    '<Account Number="236" DebitAmount="London" Amount="457656.00"/>' + 
    '<Account Number="225" DebitAmount="London" Amount="23462.40"/>' + 
    '<Account Number="236" DebitAmount="Bangalore" Amount="2345345.00"/>' + 
    '</Accounts>'; 

type 
    TIntegerArray = array of Integer; 

function GetAccountNumbers(const AXMLString: string): TIntegerArray; 
var 
    I: Integer; 
    XMLDOMNodeList: IXMLDOMNodeList; 
    XMLDOMDocument: IXMLDOMDocument3; 
begin 
    XMLDOMDocument := CoDOMDocument60.Create; 
    if Assigned(XMLDOMDocument) and XMLDOMDocument.loadXML(AXMLString) then 
    begin 
    XMLDOMNodeList := XMLDOMDocument.selectNodes('/Accounts/Account[not(@Number=preceding-sibling::Account/@Number)]/@Number'); 
    SetLength(Result, XMLDOMNodeList.length); 
    for I := 0 to XMLDOMNodeList.length - 1 do 
     Result[I] := XMLDOMNodeList.item[I].nodeValue; 
    end; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    S: string; 
    I: Integer; 
    IntegerArray: TIntegerArray; 
begin 
    S := 'Account numbers: '; 
    IntegerArray := GetAccountNumbers(XMLString); 
    for I := 0 to Length(IntegerArray) - 1 do 
    S := S + IntToStr(IntegerArray[I]) + ', '; 
    Delete(S, Length(S) - 1, 2); 
    ShowMessage(S); 
end; 

end. 

Answer 2

provare questo codice:

XMLDocument1: TXMLDocument; 

procedure TForm1.Button2Click(Sender: TObject); 
var 
    BodyNode:IXMLNode; 
    I: Integer; 
    sl:TStringList; 
begin 
    sl:=TStringList.Create; 
    XMLDocument1.Active:=False; 
    XMLDocument1.FileName:='C:\Zeina\Test.xml'; 
    XMLDocument1.Active:=True; 

    BodyNode:=XMLDocument1.DocumentElement; 
    for I:=0 to BodyNode.ChildNodes.Count-1 do 
    begin 
    if sl.IndexOf(BodyNode.ChildNodes[i].Attributes['Number'])=-1 then 
     sl.Add(BodyNode.ChildNodes[i].Attributes['Number']); 
    end; 
    Memo1.Lines:=sl; 
end; 

questo è il risultato:

Answer 3

Ziena, ho modificare il codice:

XMLDocument1: TXMLDocument; 

procedure TForm1.Button2Click(Sender: TObject); 
var 
    BodyNode:IXMLNode; 
    I: Integer; 
    sl:TStringList; 
begin 
    sl:=TStringList.Create; 
    XMLDocument1.Active:=False; 
    XMLDocument1.FileName:='C:\Zeina\Test.xml'; 
    XMLDocument1.Active:=True; 

    BodyNode:=XMLDocument1.DocumentElement; 
    sl.Duplicates := dupIgnore; 
    for I:=0 to BodyNode.ChildNodes.Count-1 do 
    sl.Add(
     BodyNode.ChildNodes[i].Attributes['Number']); // ignore duplicated lines 
    Memo1.Lines.AddStrings(sl); // for avoid memory leak 
end; 

Answer 4

Non capisco esattamente cosa si vuole raggiungere. Forse questo?

'/Accounts/Account[not(@Number=preceding-sibling::node()/@Number)]/@Number' 

Answer 5

Questo funziona nel mio XPath example in Delphi XE2 e un Delphi 2007 update of the XPath example dà questo output:

nodeName[0]:Number 
nodeValue[0]:1 
nodeName[1]:Number 
nodeValue[1]:225 
nodeName[2]:Number 
nodeValue[2]:236 

Le idee nell'esempio dovrebbe farti andare con Delphi e il 2007 utilizzando il MSXML 6 DOM, o l'OpenXML DOM (Delphi XE2 supporta MSXML 6 DOM o ADOM XML v4 DOM).

Si noti che il comportamento di MSXML 6 dipende in gran parte dalla versione effettiva installata che dipende dal sistema operativo Windows (da qui this answer).

Il che probabilmente significa che non si dispone dell'ultimo MS XML 6 installato, o che non è stato importato il giusto numero di librerie (l'unità msxml di Delphi 2007 non contiene IXMLDOMDocument2 di cui si ha bisogno per il supporto XPath).

Il 27 luglio 2012, ho dedicato un po 'di tempo per riprendere l'esempio di Delphi 2007 e testarlo.
Non sono completamente sicuro che sia completamente privo di memoria (ho hackerato una classe TDictionary per inserire le interfacce), ma i risultati sono gli stessi dell'esempio Delphi XE2 e a prima vista sembra abbastanza OK.

Nell'app demo XPathTester, caricare l'Esempio 3, quindi eseguire l'XPath (che caricherà il proprio esempio ed eseguirà l'XPath).

Si noti che la maggior parte delle altre cose nello bo library richiede almeno Delphi 2009, ma questa parte funziona.
Nelle prossime settimane lo testerò come richiesto in un altro progetto che è ancora in Delphi 2007.

procedure TMainForm.LoadXmlExample3ButtonClick(Sender: TObject); 
begin 
    LoadXmlExample([ // unique account numbers 
    '/Accounts/Account[not(@Number=preceding-sibling::Account/@Number)]/@Number' 
    ], 
    [ 
    '<?xml version="1.0"?>', 
    '<Accounts>', 
    ' <Account Number="1" DebitAmount="1000" Amount="2827561.95" />', 
    ' <Account Number="225" DebitAmount="2000" Amount="12312.00" />', 
    ' <Account Number="236" DebitAmount="London" Amount="457656.00" />', 
    ' <Account Number="225" DebitAmount="London" Amount="23462.40" />', 
    ' <Account Number="236" DebitAmount="Bangalore" Amount="2345345.00" />', 
    '</Accounts>' 
    ]); 
end;