Rieseguire un'iterazione del ciclo

Question

ho questo programma che prende un array di parole e chiede all'utente di digitare una frase che ha ciascuna parola dall'array:

@words = qw(Hi world thanks); 
foreach $word (@words) 
{ 
     print "Enter a line with word:$word\n"; 
     chomp($input = <STDIN>); 
     if($input=~/$word/i) 
     { 
       print "Great\n"; 
     } else { 
       print "Incorrect. Type a line containing $word\n"; 
     } 
} 

Se l'utente digita un ingresso con la parola, funziona bene. Ma se non lo fa Stampa solo il messaggio di errore e passa alla parola successiva. Lo voglio chiede all'utente di reinserire gli input per la stessa parola. Ma come ? Ho provato dopo non ha funzionato.

Answer 1

È possibile utilizzare un redo in questo caso su riavviare l'iterazione corrente.

foreach my $word (@words) 
{ 
     print "Enter a line with word:$word\n"; 
     chomp($input = <STDIN>); 
     if($input=~/$word/i) 
     { 
       print "Great\n"; 
     } else { 
       print "Incorrect. Type a line contaning $word\n"; 
       redo; # restart current iteration. 
     } 
} 

Un'alternativa meno consigliato è quello di utilizzare un goto:

foreach my $word (@words) 
{ 
     INPUT:print "Enter a line with word:$word\n"; 
     chomp($input = <STDIN>); 
     if($input=~/$word/i) 
     { 
       print "Great\n"; 
     } else { 
       print "Incorrect. Type a line contaning $word\n"; 
       goto INPUT; 
     } 
} 

Answer 2

vorrei creare un infinito while ciclo per uscire fuori:

#!/usr/bin/env perl 

use strict; 
use warnings; 

my @words = qw(Hi world thanks); 
foreach my $word (@words) { 
    print "Enter a line with word: $word\n"; 
    while (1) { 
    chomp(my $input = <STDIN>); 
    if($input=~/$word/i) { 
     print "Great\n"; 
     last; 
    } else { 
     print "Incorrect. Type a line contaning $word\n"; 
    } 
    } 
} 

ovviamente mi sarebbe probabilmente separata la logica di ogni singola parola in un sottotitolo, quindi si sovrappone a quello:

#!/usr/bin/env perl 

use strict; 
use warnings; 

my @words = qw(Hi world thanks); 
get_word($_) for @words; 

sub get_word { 
    my $word = shift or die "Need a word"; 
    print "Enter a line with word: $word\n"; 
    while (1) { 
    chomp(my $input = <STDIN>); 
    if($input=~/$word/i) { 
     print "Great\n"; 
     last; 
    } else { 
     print "Incorrect. Type a line contaning $word\n"; 
    } 
    } 
} 

Answer 3

Mentre redo è decisamente più cuter, ecco una versione con while ... continue. Si basa su un ciclo interno che viene abbandonato solo quando viene inserita la parola corretta e stampa una correzione per ogni risposta errata.

use strict; 
use warnings; 

my @words = qw(Hi world thanks); 
foreach my $word (@words) { 
    print "Enter a line with word: $word\n"; 
    while (my $input = <>) { 
     last if $input =~ /$word/; 
    } continue { 
     print "Incorrect. Type a line contaning $word\n"; 
    } 
    print "Great\n"; 
} 

Nota che chomp non è necessaria in questo caso.