Come sottrarre una matrice da una matrice?

Question

Quando provo seguente

#!/usr/bin/perl 

use strict; 
use warnings; 
use Data::Dumper; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

print Dumper [grep {not @bl} @a]; 

ottengo un array vuoto. Mi sarei aspettato che @bl fosse sottratto da @a, quindi l'output era yellow purple pink.

Cosa c'è che non va qui?

Answer 1

è necessario attivare @bl in un hash per eseguire la differenza set:

my %in_bl = map {$_ => 1} @bl; 
my @diff = grep {not $in_bl{$_}} @a; 

Answer 2

Vedi perlfaq4: How do I compute the difference of two arrays?

Nel codice, not probabilmente non facendo ciò che si pensa che sta facendo.

not @bl sarà sempre 1 se @bl è un array vuoto, e se undef@bl non è vuoto. Non significa "elementi non in @bl" in alcun senso.

Answer 3

@b1 viene valutata a true (si tratta di un array con un non-zero numero di elementi), quindi il test booleano nella vostra grep costrutto (not @b1) restituirà sempre false. grep filtra una matrice restituendo solo gli elementi per i quali il test booleano restituisce true.

È necessario verificare se $_ (l'elemento di matrice attualmente in considerazione) è in @bl oppure no. Un modo per farlo è quello di generare un hash temporanea utilizzando @bl come le chiavi, poi nel vostro check dichiarazione grep per la presenza di $_ nelle chiavi di hash:

#!/usr/bin/perl 

use strict; 
use warnings; 
use Data::Dumper; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

# create a hash 
my %h; 

# nifty trick - use a hash slice to populate the 
# hash. The values are irrelevant so we'll use @bl 
# for those too 
@h{@bl} = @bl; 

print Dumper [grep {!exists $h{$_}} @a]; 

Answer 4

Un altro modo, utilizzando la funzione minus dal Acme::Tools modulo CPAN:

use strict; 
use warnings; 
use Data::Dumper; 
use Acme::Tools qw(minus); 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 
my @diff = minus(\@a, \@bl); 
print Dumper(\@diff); 

__END__ 

$VAR1 = [ 
      'yellow', 
      'purple', 
      'pink' 
     ]; 

Answer 5

Un'altra opzione utilizzando perl5i:

use perl5i::2; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 
my @diff = @a->diff(\@bl); 

say @diff->mo->perl; 

Answer 6

Poiché Perl 5.18.0 l'operatore smartmatch è considerato sperimentale: The smartmatch family of features are now experimental. Per questo motivo non utilizzerei più questa soluzione.

Un altro modo con lo SmartMatch operatore (se si dispone di perl versione 5.010 o superiore):

#!/usr/bin/env perl 
use warnings; 
use 5.012; 

my @bl = qw(red green blue); 
my @a = qw(green yellow purple blue pink); 

my @s = grep{ not $_ ~~ @bl } @a; 
say "@s"; # yellow purple pink 

Answer 7

Un altro modo è quello di utilizzare:

List::Compare CPAN module 
use List::Compare ; 
... 
my $compare_obj 
    = List::Compare->new(\@a , \@b1) ; 
@diff = $compare_obj->get_Lonly() ; 
...