Utilizzo di una serie di intervalli in VBA - Excel

Question

Il supporto VBA utilizza una matrice di variabili di intervallo?

dim rangeArray() as range 
dim count as integer 
dim i as integer 

count = 3 

redim rangeArray(1 to count) 

for i = 1 to count 
    msgbox rangeArray(i).cells(1,1).value 
next 

Non riesco a farlo funzionare in questo tipo di applicazione. Voglio memorizzare una serie di intervalli in un certo ordine come "copia master". Posso quindi aggiungere, eliminare, ordinare o fare qualsiasi cosa su questo array e quindi stamparlo su una serie di intervalli in Excel. Non sembra che Excel lo sostenga: ti costringe semplicemente a memorizzare i tuoi dati nel foglio di calcolo e devi rileggerli per poterli utilizzare.

Answer 1

No, gli array non possono contenere oggetti. Ma o Gli oggetti possono contenere oggetti. Penso che ciò che potresti desiderare sia un oggetto Range che consiste in vari specifici oggetti Range. In questo esempio, rMaster è il mio "array" che contiene tre celle.

Sub StoreRanges() 

    Dim rMaster As Range 
    Dim rCell As Range 

    Set rMaster = Sheet1.Range("A1") 
    Set rMaster = Union(rMaster, Sheet1.Range("A10")) 
    Set rMaster = Union(rMaster, Sheet1.Range("A20")) 

    For Each rCell In rMaster 
     MsgBox rCell.Address 
    Next rCell 

End Sub 

Con la mia nuova conoscenza trovato che gli array possono contenere gamme (thnx jtolle), ecco un esempio di come si potrebbe memorizzare gli intervalli in un array e ordinarli

Sub UseArray() 

    Dim aRng(1 To 3) As Range 
    Dim i As Long 

    Set aRng(1) = Range("a1") 
    Set aRng(2) = Range("a10") 
    Set aRng(3) = Range("a20") 

    BubbleSortRangeArray aRng 

    For i = LBound(aRng) To UBound(aRng) 
     Debug.Print aRng(i).Address, aRng(i).Value 
    Next i 

End Sub 

Sub BubbleSortRangeArray(ByRef vArr As Variant) 

    Dim i As Long, j As Long 
    Dim vTemp As Variant 

    For i = LBound(vArr) To UBound(vArr) - 1 
     For j = i To UBound(vArr) 
      If vArr(i).Value > vArr(j).Value Then 
       Set vTemp = vArr(i) 
       Set vArr(i) = vArr(j) 
       Set vArr(j) = vTemp 
      End If 
     Next j 
    Next i 

End Sub 

Answer 2

Non è del tutto chiaro per me di cosa stai parlando.

Se stai chiedendo la possibilità di creare Range s quella mappa su nulla ed esistono da soli, allora no, non c'è modo. Un oggetto Range è solo qualcosa che fa riferimento a una determinata area di un foglio di lavoro. Non ha alcuna memoria propria o qualcosa del genere. Diverse istanze diverse della classe Range possono fare riferimento alla stessa area del foglio di lavoro.

E se vuoi solo memorizzare alcuni riferimenti in un array, allora va bene, fallo. L'unico problema con il codice è che non si inizializzano gli elementi dell'array prima di utilizzarli: poiché lo Range è un tipo di riferimento, tutti gli elementi vengono inizializzati con Nothing s per impostazione predefinita.

Answer 3

Non è del tutto chiaro che cosa si vuoi fare, ma ...

Se si desidera una raccolta, perché non utilizzare un oggetto di raccolta VBA?

Dim myRanges as New Collection 

Un Collection.Item può essere qualsiasi oggetto, tra cui un Range.

Un oggetto intervallo non contiene dati; contiene un riferimento alle celle del foglio di lavoro. Se vuoi che il range contenga il contenuto della tua collezione, dovrai copiarli in e dal foglio di lavoro.

Come con Java, le variabili VBA sono effimere, sia in una matrice che in una raccolta. Se vuoi chiudere il file e avere i dati lì quando lo apri di nuovo, devi averlo nelle celle del foglio di lavoro. I fogli di lavoro sono il tuo meccanismo di persistenza.

Ho intenzione di fare un grande salto qui, quindi se sono lontano, ignorami. Quello che penso tu stia cercando suggerisce di impostare un foglio di lavoro separato come "database", popolato con oggetti List/Table contenenti i tuoi dati grezzi. Di fronte a questo, è il tuo "foglio utente" dove fai le cose interessanti, facendo riferimento ai dati nel foglio del database. Dai un nome a tutto.