Plugin con id 'crashlytics' non trovato problema con l'ultimo plug-in Android Studio

Question

Per la seguente configurazione di gradle build, sto affrontando Error: (11, 0) Plugin con errore 'crashlytics' id non trovato.

buildscript { 
    repositories { 
     maven { url 'http://download.crashlytics.com/maven' } 
    } 

    dependencies { 
    } 
} 

apply plugin: 'android' 
apply plugin: 'crashlytics' 
apply plugin: 'hugo' 


repositories { 
    maven { url 'http://download.crashlytics.com/maven' } 
} 




android { 
    compileSdkVersion 19 
    buildToolsVersion '20.0.0' 

    defaultConfig { 
     applicationId "com.wiznsystems.android" 
     minSdkVersion 15 
     targetSdkVersion 19 
     versionCode 1 
     versionName "1.0" 
    } 
    buildTypes { 
     release { 
      runProguard false 
      proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro' 
     } 
    } 
} 

dependencies { 
    compile fileTree(dir: 'libs', include: ['*.jar']) 
    compile files('libs/smartconfiglib.jar') 
    // You must install or update the Support Repository through the SDK manager to use this dependency. 
    compile 'com.crashlytics.android:crashlytics:1.+' 
    compile 'com.android.support:support-v4:19.+' 
    compile 'com.google.android.gms:play-services:4.2.42' 
    compile 'com.jakewharton.hugo:hugo-runtime:1.1.0' 
    compile 'com.squareup.retrofit:retrofit:1.+' 
    compile 'com.android.support:appcompat-v7:19.+' 
    compile 'com.jakewharton:butterknife:5.+' 
    compile 'de.greenrobot:eventbus:2.2.1' 
    compile 'fr.avianey:facebook-android-api:+@aar' 
    compile 'com.squareup.picasso:picasso:2.+' 
    compile 'de.keyboardsurfer.android.widget:crouton:1.8.4' 
    compile project(':apptentiveandroidsdk') 
} 

Sto facendo qualcosa di sbagliato? o C'è qualche soluzione per farlo costruire?

Answer 1

Ho avuto lo stesso problema. Quello che ho finito è stato mettere l'ordine dei comandi in linea con ciò che i Crashlytics hanno fornito. Avevo qualcosa di simile al tuo e non ha funzionato. Una volta che ha cambiato l'ordine esatto dei documenti, ha funzionato. Ecco come appare ora il mio. Spero che questo ti aiuti.

buildscript { 
    repositories { 
     mavenCentral() 
     maven { url 'http://download.crashlytics.com/maven' } 
    } 
    dependencies { 
     classpath 'com.android.tools.build:gradle:0.12.+' 
     classpath 'com.crashlytics.tools.gradle:crashlytics-gradle:1.+' 
    } 
} 

apply plugin: 'android' 
apply plugin: 'crashlytics' 

repositories { 
    mavenCentral() 
    maven { url 'http://download.crashlytics.com/maven' } 
} 

dependencies { 
    compile fileTree(dir: 'libs', include: ['*.jar']) 
    compile 'com.android.support:appcompat-v7:19.+' 
    compile 'com.android.support:support-v4:19.0.+' 
    compile 'com.squareup.picasso:picasso:2.3.2' 
    compile 'com.joanzapata.android:android-iconify:1.0.6' 
    compile 'com.github.hotchemi:android-rate:0.3.1' 
    compile 'com.loopj.android:android-async-http:1.4.5' 
    compile 'com.github.satyan:sugar:1.3' 
    compile 'com.crashlytics.android:crashlytics:1.+' 
} 

android { 
    compileSdkVersion 19 
    buildToolsVersion "20" 

defaultConfig { 
    minSdkVersion 14 
    targetSdkVersion 19 
    versionCode 1 
    versionName "1.0" 
} 
buildTypes { 
    release { 
     runProguard false 
     proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt' 
    } 
} 
} 

Answer 2

Prova informare la dipendenza classpath:

buildscript { 
    repositories { 
     maven { url 'http://download.crashlytics.com/maven' } 
    } 

    dependencies { 
     classpath 'com.crashlytics.tools.gradle:crashlytics-gradle:1.+' 
    } 
} 

Answer 3

Dopo aver combattuto con questo errore per ore, ho finito per l'eliminazione della cartella ".gradle" sulla mia home directory, e la questione svanì! Quindi, se riscontri questo problema, prova prima a eliminare la cartella .gradle, quindi ricostruisci il progetto.