Regex con espressione ricorsiva per abbinare le parentesi graffe nidificate?

Question

Sto tentando di abbinare il testo come sp { ...{...}... }, dove è consentito il nidificazione delle parentesi graffe. Questo è quello che ho finora:

my $regex = qr/ 
(     #save $1 
    sp\s+   #start Soar production 
    (    #save $2 
     \{   #opening brace 
     [^{}]*  #anything but braces 
     \}   #closing brace 
     | (?1)  #or nested braces 
    )+    #0 or more 
) 
/x; 

non riesco proprio a farlo per abbinare il seguente testo: sp { { word } }. Qualcuno può vedere cosa c'è di sbagliato nella mia espressione regolare?

Answer 1

Ci sono numerosi problemi. Il bit dovrebbe essere ricorsiva:

(
    (?: \{ (?-1) \} 
    | [^{}]+ 
    )* 
) 

Tutti insieme:

my $regex = qr/ 
    sp\s+ 
    \{ 
     (
     (?: \{ (?-1) \} 
     | [^{}]++ 
     )* 
    ) 
    \} 
/x; 

print "$1\n" if 'sp { { word } }' =~ /($regex)/; 

Answer 2

Si tratta di caso per il sottoutilizzata Text::Balanced, un modulo di base molto utile per questo genere di cose. Essa si basa sul pos di inizio della sequenza delimitata essere trovato/set prima, così io di solito invocare in questo modo:

#!/usr/bin/env perl 

use strict; 
use warnings; 

use Text::Balanced 'extract_bracketed'; 

sub get_bracketed { 
    my $str = shift; 

    # seek to beginning of bracket 
    return undef unless $str =~ /(sp\s+)(?={)/gc; 

    # store the prefix 
    my $prefix = $1; 

    # get everything from the start brace to the matching end brace 
    my ($bracketed) = extract_bracketed($str, '{}'); 

    # no closing brace found 
    return undef unless $bracketed; 

    # return the whole match 
    return $prefix . $bracketed; 
} 

my $str = 'sp { { word } }'; 

print get_bracketed $str; 

L'espressione regolare con il modificatore gc dice la stringa di ricordare dove il punto finale di la partita è, e extract_bracketed usa queste informazioni per sapere da dove iniziare.