TStringList - strano comportamento

Question

Delphi 1 a 16 bit (sì è vecchio, ma funziona bene)

Alcuni codice di esempio:

procedure TForm1.Button1Click(Sender: TObject); 
var 
    SL: TStringList; 
begin 

    SL := TStringList.Create; 
    SL.Sorted := True; 
    SL.Duplicates := dupIgnore; 

    SL.AddObject('A', TObject(100)); 
    SL.AddObject('A', TObject(999)); 
    ShowMessage(IntToStr(LongInt(SL.Objects[0]))); {A} 

    SL.Free; 

end; 

Sto utilizzando il campo oggetto per memorizzare longints (un hack sì, ma ha fatto il lavoro). Ad ogni modo, alla riga A sopra mi aspetto che ShowMessage mostri 100, invece mostri 999 (anche se dupIgnore è impostato). Mi sto perdendo qualcosa qui? O dovrebbe funzionare in questo modo (mi aspettavo che la lista di stringhe ignorasse la 999)?

Answer 1

Appena testato in Delphi 2009 - mostra 100 (e dovrebbe mostrare 100 secondo la documentazione di Delphi 2009 su Duplicati e dupIgnore).

Probabilmente si tratta di Delphi 1 bug.

---

Aggiornato

@Sertac Akyuz: Sì, che sembra essere vero. Google shows che le vecchie versioni di Delphi hanno avuto la seguente applicazione di metodi e TStringList.Add TStringList.AddObject:

function TStringList.Add(const S: string): integer; 
begin 
    if not Sorted then 
    Result := FCount 
    else 
    if Find(S, Result) then 
     case Duplicates of 
     dupIgnore: Exit; 
     dupError: Error(SDuplicateString, 0); 
     end; 
    InsertItem(Result, S); 
end; 

function TStrings.AddObject(const S: string; AObject: TObject): Integer; 
begin 
    Result := Add(S); 
    PutObject(Result, AObject); 
end; 

L'attuale (Delphi 2009) implementazione è:

function TStringList.Add(const S: string): Integer; 
begin 
    Result := AddObject(S, nil); 
end; 

function TStringList.AddObject(const S: string; AObject: TObject): Integer; 
begin 
    if not Sorted then 
    Result := FCount 
    else 
    if Find(S, Result) then 
     case Duplicates of 
     dupIgnore: Exit; 
     dupError: Error(@SDuplicateString, 0); 
     end; 
    InsertItem(Result, S, AObject); 
end; 

vedere la differenza. La vecchia implementazione può essere vista come un bug (perdita di memoria, ecc.) O un comportamento consentito non documentato. In ogni caso l'implementazione attuale è esente dal problema.

Answer 2

Non ti manca nulla. Questo è esattamente quello che succede.

AddObject inizia chiamando Add, che restituisce l'indice del nuovo (o esistente) elemento nell'elenco. Quindi chiama PutObject per assegnare il valore dell'oggetto a quell'indice. Il comportamento rispetto alla proprietà Duplicates non è specificato nella documentazione.